00010 rem Portability enhancement by David Meyer (2012/2/3)
00020 print tab(31);"23 MATCHES"
00030 print tab(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
00040 print
00041 print
00042 print
00050 print " THIS IS A GAME CALLED '23 MATCHES'."
00060 print
00070 print "WHEN IT IS YOUR TURN, YOU MAY TAKE ONE, TWO, OR THREE"
00080 print "MATCHES. THE OBJECT OF THE GAME IS NOT TO HAVE TO TAKE"
00090 print "THE LAST MATCH."
00100 print
00110 print "LET'S FLIP A COIN TO SEE WHO GOES FIRST."
00120 print "IF IT COMES UP HEADS, I WILL WIN THE TOSS."
00130 print
00140 rem
00150 N=23
00160 Q=INT(2*RND*5)
00170 if Q=1 then goto 210
00180 print "TAILS! YOU GO FIRST. "
00190 print
00200 goto 290
00210 print "HEADS! I WIN! HA! HA!"
00220 print "PREPARE TO LOSE, MEATBALL-NOSE!!"
00230 print
00240 print "I TAKE 2 MATCHES"
00250 N=N-2
00260 print "THE NUMBER OF MATCHES IS NOW";N
00270 print
00280 print "YOUR TURN -- YOU MAY TAKE 1, 2 OR 3 MATCHES."
00290 print "HOW MANY DO YOU WISH TO REMOVE",
00300 input K
00310 if K>3 then goto 510
00320 if K<=0 then goto 510
00330 N=N-K
00340 print "THERE ARE NOW";N;" MATCHES REMAINING."
00350 if N=4 then goto 420
00360 if N=3 then goto 440
00370 if N=2 then goto 460
00380 if N<=1 then goto 610
00390 Z=4-K
00400 goto 470
00410 print
00420 Z=3
00430 goto 470
00440 Z=2
00450 goto 470
00460 Z=1
00470 print "MY TURN ! I REMOVE";Z;" MATCHES"
00480 N=N-Z
00490 if N<=1 then goto 550
00500 goto 260
00510 print "VERY FUNNY! DUMMY!"
00520 print "DO YOU WANT TO PLAY OR GOOF AROUND?"
00530 print "NOW, HOW MANY MATCHES DO YOU WANT",
00540 goto 300
00550 print
00560 print "YOU POOR BOOB! YOU TOOK THE LAST MATCH! I GOTCHA!!"
00570 print "HA ! HA ! I BEAT YOU !!!"
00580 print
00590 print "GOOD BYE LOSER!"
00600 goto 640
00610 print "YOU WON, FLOPPY EARS !"
00620 print "THINK YOU'RE PRETTY SMART !"
00630 print "LETS PLAY AGAIN AND I'LL BLOW YOUR SHOES OFF !!"
00640 end
00650